ContactsPickerDialog.qml

/* Copyright (C) 2025 CIT-Services <info@cit-services.eu>
 
   This file is part of Dekko email client for Ubuntu devices
 
   This program is free software; you can redistribute it and/or
   modify it under the terms of the GNU General Public License as
   published by the Free Software Foundation; either version 2 of
   the License or (at your option) version 3
 
   This program is distributed in the hope that it will be useful,
   but WITHOUT ANY WARRANTY; without even the implied warranty of
   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
   GNU General Public License for more details.
 
   You should have received a copy of the GNU General Public License
   along with this program.  If not, see <http://www.gnu.org/licenses/>.
*/
import QtQuick 2.4
import Lomiri.Components 1.3
import Lomiri.Components.Popups 1.0 as Popups
import Lomiri.Content 1.1
 
Popups.PopupBase {
    id: picker
    z: 100
    property var activeTransfer
    signal contactsImported(var files)
 
    Rectangle {
        anchors.fill: parent
 
        ContentTransferHint {
            anchors.fill: parent
            activeTransfer: picker.activeTransfer
        }
 
        ContentPeerPicker {
            id: peerPicker
            anchors.fill: parent
            visible: true
            contentType: ContentType.Contacts
            handler: ContentHandler.Source
 
            onPeerSelected: {
                peer.selectionType = ContentTransfer.Multiple
                picker.activeTransfer = peer.request()
                stateChangeConnection.target = picker.activeTransfer
            }
            onCancelPressed: {
                PopupUtils.close(picker)
            }
        }
    }
 
    Connections {
        id: stateChangeConnection
        ignoreUnknownSignals: true
        onStateChanged: {
            if (picker.activeTransfer && picker.activeTransfer.state === ContentTransfer.Charged) {
                var files = new Array();
                for (var i = 0; i < picker.activeTransfer.items.length; i++) {
                    files.push(picker.activeTransfer.items[i].url)
                }
                picker.contactsImported(files);
                PopupUtils.close(picker);
            }
        }
    }
}