MessageHeader.qml

/* Copyright (C) 2016 - 2017 Dan Chapman <dpniel@ubuntu.com>
 
   This file is part of Dekko email client for Ubuntu devices
 
   This program is free software; you can redistribute it and/or
   modify it under the terms of the GNU General Public License as
   published by the Free Software Foundation; either version 2 of
   the License or (at your option) version 3
 
   This program is distributed in the hope that it will be useful,
   but WITHOUT ANY WARRANTY; without even the implied warranty of
   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
   GNU General Public License for more details.
 
   You should have received a copy of the GNU General Public License
   along with this program.  If not, see <http://www.gnu.org/licenses/>.
*/
import QtQuick 2.4
import Lomiri.Components 1.3
import Lomiri.Components.Popups 1.3
import Dekko.Components 1.0
import Dekko.Mail 1.0
import Dekko.Mail.API 1.0
import Dekko.Mail.Settings 1.0
import Dekko.Lomiri.Components 1.0
import Dekko.Lomiri.Constants 1.0
import "../utils/UiUtils.js" as UiUtils
 
ListItem {
    id: messageHeader
    property var msg
    property bool detailsVisible: false
    width: parent.width
    height: defaultLayout.height
    divider.visible: false
 
    signal showDetails()
 
    ListItemLayout {
        id: defaultLayout
        title.text: msg.from.name
        title.elide: Text.ElideRight
        title.wrapMode: Text.NoWrap
        subtitle.text: msg.toRecipientsString
        subtitle.elide: Text.ElideRight
        subtitle.wrapMode: Text.NoWrap
        summary.text: detailsVisible ? qsTr("Hide details") : qsTr("View details")
        summary.color: LomiriColors.blue
        // Hack to re-parent the mousearea to the summary label.
        // so we can make it clickable.
        Component.onCompleted: mouseArea.parent = defaultLayout.summary
 
        MouseArea {
            id: mouseArea
            parent: defaultLayout.summary
            anchors.fill: parent
            onClicked: messageHeader.showDetails()
        }
 
        Avatar {
            id: avatar
            name: msg.from.name
            initials: msg.from.initials
            email: msg.from.address
            validContact: true
            fontSize: "large"
            SlotsLayout.position: SlotsLayout.Leading
        }
 
        Item {
            id: inner_infoCol
 
            width: (zoomColumn.width + infoActionColumn.width)
            height: zoomColumn.height
            SlotsLayout.overrideVerticalPositioning: true
 
            Column {
                id: zoomColumn
                anchors.right: infoActionColumn.left
                anchors.bottom: parent.bottom
                spacing: 0
 
                HeaderButton {
                    id: zoomInButton
                    height: units.gu(4)
                    width: units.gu(4)
                    action: Action {
                        iconName: "zoom-in"
                        onTriggered: webview.zoomFactor = webview.zoomFactor * 1.1
                    }
                }
 
                HeaderButton {
                    id: zoomOutButton
                    height: units.gu(4)
                    width: units.gu(4)
                    action: Action {
                        iconName: "zoom-out"
                        onTriggered: webview.zoomFactor = webview.zoomFactor * 0.9
                    }
                }
            }
 
            Column {
                id: infoActionColumn
                anchors.right: parent.right
                anchors.bottom: parent.bottom
                spacing: 0
 
                // wrap Label in item with same size as upper zoom button for same vertical aligment
                Item {
                    width: inner_timeLabel.implicitWidth
                    height: zoomInButton.height
                    anchors.right: parent.right
 
                    Label {
                        id: inner_timeLabel
                        anchors.verticalCenter: parent.verticalCenter
                        text: msg ? msg.prettyDate : ""
                        fontSize: "small"
                    }
                }
 
                Row {
                    id: buttonRow
                    anchors.right: parent.right
                    anchors.rightMargin: -units.gu(0.5)
                    spacing: 0
 
                    HeaderButton {
                        id: reply
                        height: units.gu(4)
                        width: units.gu(4)
                        iconColor: LomiriColors.ash
                        action: Action {
                            iconSource: Paths.actionIconUrl(Icons.MailReplyIcon)
                            onTriggered: ComposerActions.respondToMessage(msg.isListPost ? SubmissionManager.ReplyList : SubmissionManager.Reply, msg.messageId)
                        }
                    }
 
                    HeaderButton {
                        id: contextmenu
                        height: units.gu(4)
                        width: units.gu(4)
                        iconColor: LomiriColors.ash
                        action: Action {
                            iconSource: Paths.actionIconUrl(Icons.ContextMenuIcon)
                            onTriggered: PopupUtils.open(Qt.resolvedUrl("../popovers/MessageActionPopover.qml"), contextmenu, {msg: msg})
                        }
                    }
                }
            }
        }
    }
}